the influence of equalDof on period

[MRG]

Dear all,
i have simple onebay onestory frame with pin connection , i model it in Sap and Opensees , period in Sap is
4.84s with using Constraint in direction 1 (x) for the ends of Beam but when i model tit in opensees and i use
" equalDOF 2 4 1 " i get the period equal to 0.18s .Also in opensees when i dont use " equalDOF 2 4 1 " i get the period equal to 4.93s . Please Help me !
Thanks for your time and best regards.


wipe
model basic -ndm 2 -ndf 3
# Coordinates
node 1 -3.048 0
node 2 -3.048 3.9624
node 3 3.048 0
node 4 3.048 3.9624

# fix supports
fix 1 1 1 1
fix 3 1 1 1

# Assign Masses
mass 2 2696.58 1e-20 1e-20
mass 4 2696.58 1e-20 1e-20

# Define extra nodes for modeling pin connections and equal Dofs
node 7 -3.048 3.9624
node 8 3.048 3.9624
equalDOF 2 7 1 2
equalDOF 4 8 1 2

# Define Materials
set Bemat 1000
set E_Bemat 21000000000
set Fy_Bemat 25310506.54
set H_Ratio_Bemat 0.02
uniaxialMaterial Steel02 $Bemat $Fy_Bemat $E_Bemat $H_Ratio_Bemat 18.5 0.925 0.15
set colmat 1001
set E_colmat 21000000000
set Fy_colmat 35153481.31
set H_Ratio_colmat 0.02
uniaxialMaterial Steel02 $colmat $Fy_colmat $E_colmat $H_Ratio_colmat 18.5 0.925 0.15

# Define Frame Sections
proc Wsection { secID matID d bf tf tw nfdw nftw nfbf nftf} {
set dw [expr $d-2*$tf]
set y1 [expr -$d/2.]
set y2 [expr -$dw/2.]
set y3 [expr $dw/2.]
set y4 [expr $d/2.]
set z1 [expr -$bf/2.]
set z2 [expr -$tw/2.]
set z3 [expr $tw/2.]
set z4 [expr $bf/2.]
section fiberSec $secID {
patch quad $matID $nftf $nfbf $y3 $z1 $y4 $z1 $y4 $z4 $y3 $z4
patch quad $matID $nfdw $nftw $y2 $z2 $y3 $z2 $y3 $z3 $y2 $z3
patch quad $matID $nftf $nfbf $y1 $z1 $y2 $z1 $y2 $z4 $y1 $z4
}
}
Wsection 1 $colmat 0.1 0.1 0.01 0.006 15 6 8 6
Wsection 2 $Bemat 0.24 0.12 0.0098 0.0062 27 10 10 10

# Define Elements ; two Columns and one Beam
geomTransf Linear 1
set numIntgrPtsC 6
element nonlinearBeamColumn 1 1 2 $numIntgrPtsC 1 1 -mass 0.0
element nonlinearBeamColumn 2 3 4 $numIntgrPtsC 1 1 -mass 0.0

geomTransf Linear 2
set numIntgrPtsB 6
element nonlinearBeamColumn 3 7 8 $numIntgrPtsB 2 2 -mass 0.0
# Equal Dof Ends of Beam in dof 1
equalDOF 2 4 1

# Getting Period
set eigs "[eigen 2]"
puts "Eigen Values:"
puts "$eigs"
for {set i 1} {$i<=[llength $eigs]} {incr i} {
set p [lappend p [expr 2*3.1415/pow([lindex $eigs [expr $i-1]],0.5)]]
}
puts "
Periods:"
puts "$p"

[fmk]

you cannot have a retained dof being a constrained dof in another constraint in OpenSees when using the transformation constraint handler (defaut if only eigen specified).

create an analysis with a Penalty constraint handler before you issue the eigen command, i.e. something like:

system ProfileSPD
numberer Plain
constraints Penalty 1e12 1e12
integrator Newmark 0.5 0.25
analysis Transient

[MRG]

dear fmk
the problem is solved
thank you very much.