frame with simple ( pin ) beam to column connection

[a_farhid]

Since many operators need to know how to model a pinned or simple beam to column connection, I wrote and posted a 2D 1-story 1-bay steel frame with this feature. I hope it helps other students with confusion between zeroLengthElement and equalDOF. The results are exactly the same as SAP2000.

# Example: frame with simple beam to column connection
# linearBeamColumn elements
# Static Analysis
# by Alireza Farhidzadeh Feb. 2010
#
#gravity 2500kg/m; Lateral Load=1000kg
#
#.................|||||2500kg/m||||
#1000kg--->3_____(3)____4
# ................|........................|
# ................|........................|
# ...........(1) |........................|(2)
#.................|........................|
#...............=1=...................=2=....
#

wipe;
model basic -ndm 2 -ndf 3;
file mkdir DataFramePin;
# define Units--------------------------------------------
set m 1;
set cm [expr 0.01*$m];
set cm2 [expr $cm*$cm];
set cm4 [expr $cm*$cm*$cm*$cm];
set m2 [expr $m*$m];

set N 1;
set sec 1;
set g [expr 9.8066502*$m/pow($sec,2)]
set kg [expr $N*$g];

# Define geometry ---------------------------------------------
#define coordiantes
set LCol [expr 3*$m];
set LBeam [expr 5*$m];
node 1 0 0;
node 2 $LBeam 0;
node 3 0 $LCol ;
node 33 0 $LCol ; #slave node for releasing moment at beam ends
node 4 $LBeam $LCol ;
node 44 $LBeam $LCol ; #slave node for releasing moment at beam ends

#define Boundary conditions
fix 1 1 1 1;
fix 2 1 1 1;
fix 3 0 0 0;
fix 4 0 0 0;

#Vertical and Horizontal displacements of master node linked to slave node leading to releasing moment at beam ends
equalDOF 3 33 1 2;
equalDOF 4 44 1 2;

#define nodal Masses
set BeamLoad [expr 1000*$kg/$m2*2.5*$m]
mass 3 [expr $BeamLoad*$LBeam/2] 0. 0.;
mass 4 [expr $BeamLoad*$LBeam/2] 0. 0.;

# Define element------------------------------------------------
geomTransf Linear 1;

set A [expr 23.9*$cm2];
set I [expr 1317*$cm4];
set E [expr 2038696.1*$kg/$cm2]
element elasticBeamColumn 1 1 3 $A $E $I 1; # Left column
element elasticBeamColumn 2 2 4 $A $E $I 1; # Right column
element elasticBeamColumn 3 33 44 $A $E $I 1; # beam

#Define Recorders-------------------------------------------------------
recorder Node -file DataFramePin/DFree.out -time -node 3 -dof 1 2 3 disp;
recorder Node -file DataFramePin/DFreeTest.out -time -node 33 -dof 1 2 3 disp;
recorder Node -file DataFramePin/RBase1.out -time -node 1 -dof 1 2 3 reaction;
recorder Node -file DataFramePin/RBase2.out -time -node 2 -dof 1 2 3 reaction;
recorder Element -file DataFramePin/FColLeft.out -time -ele 1 localForce;
recorder Element -file DataFramePin/FColRight.out -time -ele 2 globalForce;
recorder Element -file DataFramePin/FBeam.out -time -ele 3 globalForce;

#Define Gravity -----------------------------------------------------
pattern Plain 1 Linear {
eleLoad -ele 3 -type -beamUniform [expr -1*$BeamLoad]
load 3 [expr 1000*$kg] 0. 0.;
}
constraints Plain; # how it handles boundary conditions
numberer Plain; # renumber dof's to minimize band-width (optimization), if you want to
system BandGeneral; # how to store and solve the system of equations in the analysis
test NormDispIncr 1.0e-8 6 ; # determine if convergence has been achieved at the end of an iteration step
algorithm Newton; # use Newton's solution algorithm: updates tangent stiffness at every iteration
integrator LoadControl 0.1; # determine the next time step for an analysis, # apply gravity in 10 steps
analysis Static # define type of analysis static or transient
analyze 10; # perform gravity analysis
loadConst -time 0.0; # hold gravity constant and restart time

[hnsmengyu]

get it
Thanks!