Multiaxial Cyclic Plasticity

[perou]

Multiaxial Cyclic Plasticity, developed by Prof. Sitar and B. Wang, was added in version 1.6.2. It applies to plane strain and axisymmetric cases. Will you please provide some examples and the commands. I couldn't find anything in the manual or the examples.

Thank you

[Gang Wang]

and add the command in the mannual. It will happen in a couple of days.
To be more correct, the model is developed for 3D, planestrain, and
axisymmetric cases, that is why it is called a multi-axial model.

[ahmetalperparker]

also will you add the related references about the plasticity model?
regards...
Ahmet Alper Parker

[Gang Wang]

This command constructs a MultiaxialCyclicPlasticity material object, which can be used in 3D, 2D plane strain, and 2D axisymmetric analysis. The model is based on bounding surface concept. For the volumetric response, the stress-strain relationship is linearly elastic, as specified by a constant bulk modulus $K. For the deviatoric response, the stress-strain relationship is fully nonlinear --- the shear modulus degradates smoothly from initial value, $Gmax, to its residual value when the stress state reaches the bounding surface. Two hardening parameters $h and $m are used to describe the evolution of nonlinearity. The bounding surface is of the Von Mises type, and it can exhibit linear kinematic hardening according to parameter $Ho. This material can be used to simulate undrained cyclic behavior of clays.
=============================================================
nDMaterial MultiaxialCyclicPlasticity $tag $rho $K $Gmax $Su $Ho $h $m $beta $Kcoeff
=============================================================
$tag unique material object integer tag
$rho Mass density
$K Bulk modulus
$Gmax Maximum (small strain) Shear modulus
$Su Undrained shear strength
$Ho Linear kinematic hardening parameter of bounding surface
$h Exponential hardening parameter
$m Exponential hardening parameter
$beta Integration parameter (use $beta=0.5 for midpoint rule)
$Kcoeff Coefficient of earth pressure

NOTE:
1. The undrained shear strength $Su is obtained from unconfined compression test ($Su=q/2), and it defines the radius R of bounding surface (R=sqrt(8/3)*Su);
2. The coefficient of earth pressure $Kcoeff is designed to prescribe correct lateral pressure for consolidation under self weight. It is activated by calling a command for updating material stage. By default, this parameter is not used. So right now, just give it any number.

Reference:
Borja, RI and A.P. Amies, "Multiaxial cyclic plasticity model for clays," Journal of Geotechnical Engineering, ASCE, 120(6), 1994, 1051-1070

Wang, G. and N. Sitar. “Nonlinear Analyses of Drilled Piers under Dynamic and Static Axial Loading,” Eighth U.S. National Conference on Earthquake Engineering, April 18-22, 2006, San Francisco. http://www.ce.berkeley.edu/~wang/papers/8NCEEPaper.pdf

[Gang Wang]

#*****************************************
# #
# Cyclic Simple Shear Test for Clays #
# #
# MultiAxialCyclicPlasticity Model #
# #
# Gang Wang and Nicholas Siter #
# #
# CEE, University of California, Berkeley #
# #
# June 4, 2004 #
# #
#*****************************************#

# ################################
# create the modelbuilder
# #################################

wipe

model BasicBuilder -ndm 2 -ndf 2

set displayMode "displayON"

set totalDisp 0.3; # shear to totalDisp in percentage
set Steps1 100; # virgin loading
set Steps2 [expr 2*$Steps1]; # unloading steps
set Steps3 [expr 2*$Steps1]; # reloading steps


# ################################
# build the model
# #################################


# build a element of length L and height H
#
# y /\
# |
# |
# 3 O-------O 4
# | |
# | (1) | H
# | |
# 1 O-------O 2 ----> x
# L

################################
## ##
## SPECIMEN ##
## ##
################################

## length and height of specimen
set L 100;
set H 100;

node 1 0 0
node 2 $L 0
node 3 0 [expr $H]
node 4 $L [expr $H]


fix 1 1 1
fix 2 1 1
fix 3 0 1
fix 4 0 1
equalDOF 3 4 1

###############################
## ##
## MATERIAL ##
## ##
###############################
set E [expr 5.0e8]; # Young's Modulus (in Pa)
set v 0.49; # Poisson's Ratio
set K [expr $E/(3*(1-2*$v))]; # bulk modulus
set Gmax [expr $E/(2*(1+$v))]; # maximum shear modulus
set rho_soil 2000.0; # density
set Ho [expr $Gmax/300.0] ; # hardening modulus of bounding surface
set h [expr 0.8*$Gmax]; # hardening parameter
set m 0.8; # hardening parameter
set Su 1.0e5; # undrained shear strength
set beta 0.5; # integration parameter, 0.5 for midpoint rule
set K0 0.5; # coefficient of earthpressure, just give a number
nDMaterial MultiaxialCyclicPlasticity 1 $rho_soil $K $Gmax $Su $Ho $h $m $beta $K0
################################
## ##
## ELEMENT ##
## ##
################################

set matNum 1
element quad 1 1 2 4 3 1 PlaneStrain $matNum



################################
## ##
## LOAD ##
## ##
################################

# Constant point load
pattern Plain 1 Linear {
load 3 1 0
load 4 1 0
}


################################
## ##
## ANALYSIS ##
## ##
################################

# create the analysis

###### virgin Loading ###############
set SingleStep [expr $totalDisp/$Steps1]
integrator DisplacementControl 3 1 $SingleStep
numberer RCM
#constraints Penalty 1e19 1e19
constraints Plain
set Threshhold 1.0e-16
test NormDispIncr $Threshhold 50 1
#test EnergyIncr $Threshhold 50 1

algorithm Newton
numberer RCM
system ProfileSPD
analysis Static

recorder Node -file nodedisp.out -time -node 3 -dof 1 disp
recorder plot nodedisp.out TopNodeDisp 10 10 500 450 -columns 1 2

# ################################
# perform the analysis
# #################################

analyze $Steps1
print node 3 4

##### 2nd Loading ###################
loadConst
setTime 0.0
pattern Plain 2 Linear {
load 3 -1 0
load 4 -1 0
}

integrator DisplacementControl 3 1 [expr -1.0*$SingleStep];
analyze $Steps2
print node 3 4

##### 3rd Loading #################
loadConst
setTime 0.0
pattern Plain 3 Linear {
load 3 1 0
load 4 1 0
}
integrator DisplacementControl 3 1 [expr 1.0*$SingleStep];
analyze $Steps3
print node 3 4

[perou]

Thanks Gang for your quick answers. The example you posted works well even with the bbarQuad element. I have three questions:

1) how do you model a Multiaxial Cyclic Plasticity axisymmetric problem? in your two papers with Prof. Sitar you used axisymmetric analysis. I tried defining the material nDMaterial MultiaxialCyclicPlasticityAxiSymm but it didn't work, I got an error message.

2) how do you use the Drucker Prager model you used in your EM 2004 paper. It was also used with axisymmetric and bbarQuad elements

3) how do you get stresses from the bbarQuad element. I tried the command: recorder Element all -file sg1.out material 1 stress but I get only an empty file sg1.out. The manual does not give the valid queries for the bbarQuad element.

I appreciate in advance your answers.

Best Regards

[Gang Wang]

Hello Perou,
All your three questions can boil down to one answer: I have modified bbarQuad formulation to include (1) the axisymmetric case (2) self weight, and (3) a stress recorder to give stress state at Gaussian points, since the current version is incapable of doing all these. However, the modified element is not uploaded into reporotory.
If it is of a great interest to be used by many, I should upload it soon.

[perou]

Gang,

I think it would be very useful if you could include the bbarQuad element for axisymmetric problems you coded.

This would be the only axisymmetric element for plasticity analysis in OpenSees. In addition, since until now we still don't have quad elements with reduced integration in OpenSees, this would be the only element that mitigates volumetric locking.

Thanks and regards.