P Delta Effects in Zerolength Element

[Jeena]

Hi all,

I am modeling a 5 story wood shear wall building with only 'zeroLength' elements. Each wall is represented as a zerolength element and material properties assigned to it.

Is there a way to include P Delta effects to this zeroLength element ??


Thanks,
Jeena

[mhscott]

Use a zero length element with elastic uniaxial material of stiffness -P/L

[omaramin]

Hi Jeena,

Did you end up using the suggested method?... how did you incorporate it into your model and how were the results?

Thanks!

[Jeena]

Hey,

I eventually implemented the P-Delta effects by adding a P-Delta leaning column.

The leaning column is modeled as a elastic beam column element with moment releases at top and bottom ... These leaning columns were added to the floor level of the shear wall by a truss element ...

The results looks as I expected ... P-Delta effects reduced the total base shear ...

Would you like to see a simple 2 story model ??

Thanks,
Jeena

[omaramin]

Yeah that will be great... thanks a lot!

[Jeena]

Hi,

Here is a 2 story shear wall model in 2D.

Shear walls - modeled with zero length element at floor levels
Truss elements connect between the floor levels along the height of the building
Truss element connect the floors to the P-Delta column line
Elastic beam column element for leaning column elements ..

Here is the complete geometry of the model

wipe all; # clear memory of past model definitions

model BasicBuilder -ndm 2 -ndf 3; # Define the model builder, ndm = #dimension, ndf = #dofs
source rotLeaningCol.tcl; # procedure for defining a rotational spring (zero-length element) with very small stiffness

###################################################################################################
# Define Building Geometry, Nodes, and Constraints
###################################################################################################

# define structure-geometry parameters
set nStories 2; # number of stories
set nWalls 1; # number of walls in each story
set lWall [expr 40.0*12.0]; # wall length in inches
set hWall [expr 10.0*12.0]; # story height in inches
set hBuilding [expr $hWall*$nStories]; # height of building

# calculate locations of walls/column joints:
set Pier1 0.0; # leftmost column line
set Pier2 [expr $Pier1 + $lWall]; # P-delta column line

set Floor1 0.0; # ground floor
set Floor2 [expr $Floor1 + $hWall];
set Floor3 [expr $Floor2 + $hWall];

# calculate nodal masses -- lump floor masses at frame nodes
set g 386.2; # acceleration due to gravity
set Floor2Weight 82.0; # tributary weight of Floor 2 to the design wall in kips
set Floor3Weight 41.0; # tributary weight of Floor 3 to the design wall in kips
set WBuilding [expr $Floor2Weight + $Floor3Weight]; # total building weight to the design walls
set NodalMass2 [expr ($Floor2Weight/$g) / ($nWalls)]; # mass on Floor 2 to the design wall in kips
set NodalMass3 [expr ($Floor3Weight/$g) / ($nWalls)]; # mass on Floor 3 to the design wall in kips
set Negligible 1e-9; # a very small number to avoid problems with zero

# calculate gravity loads in floor levels

set FloorLoad2 30.0; # floor load in psf
set FloorLoad3 30; # floor load in psf
set LengthX 40.0; # Wall length is 40 ft
set LengthY 40.0; # Tributary length of building to the wall

set Pfloor2 [expr ($FloorLoad2*$LengthX*$LengthY/1000)]; #floor load at 2nd floor

set Pfloor3 [expr ($FloorLoad3*$LengthX*$LengthY/1000)]; #


## Nodes for shear wall

# command: node nodeID xcoord ycoord -mass mass_dof1 mass_dof2 mass_dof3

# Wall coordinates

node 111 $Pier1 $Floor1;
node 120 $Pier1 $Floor2 ;
node 121 $Pier1 $Floor2 -mass $NodalMass2 $NodalMass2 $Negligible;
node 130 $Pier1 $Floor3
node 131 $Pier1 $Floor3 -mass $NodalMass3 $NodalMass3 $Negligible;

# Leaning column coordinates # assigned at a column line to the end of the assigned wall

node 211 $Pier2 $Floor1; # no mass assigned to leaning columns
node 221 $Pier2 $Floor2
node 2211 $Pier2 $Floor2
node 22111 $Pier2 $Floor2
node 231 $Pier2 $Floor3
node 2311 $Pier2 $Floor3


set Floor_ID(0,1) 121
set Floor_ID(1,1) 131

set Mass_ID(0,1) $NodalMass2
set Mass_ID(1,1) $NodalMass3

set NodeRecord 131

#------------------------------------------------------------------------------------------------

# assign boundary conditions

# command: fix nodeID dxFixity dyFixity rzFixity

# fixity values: 1 = constrained; 0 = unconstrained
# fix the base of the building; pin P-delta column at base

fix 111 1 1 1;
fix 120 1 1 1;
fix 121 0 1 1;
fix 130 0 1 1;
fix 131 0 1 1;


fix 211 1 1 0; # P-delta column is pinned
fix 221 0 0 0;



#constrain joints in a floor to have the same lateral displacement using the "equalDOF" command

# command: equalDOF $MasterNodeID $SlaveNodeID $dof1 $dof2...

set dof1 1; # constrain movement in dof 1 (x-direction)

equalDOF 121 130 $dof1; # Wall 1: Bottom node of floor 2 slaved to top node of floor 1

equalDOF 121 221 $dof1; # Floor 2: Top node of Wall 1 in floor 2 slaved to node in leaning column in the same level
equalDOF 131 231 $dof1; # Floor 2: Top node of Wall 2 in floor 2 slaved to node in leaning column in the same level


puts "Geometry Data Taken"


###################################################################################################
# Define Section Properties and Elements
###################################################################################################
# define material properties


## Shear Wall Materials

#uniaxialMaterial SAWS 1 $F0 $FI $DU $S0 $R1 $R2 $R3 $R4 $alph $bet

# Story 1
uniaxialMaterial SAWS 1 41.7357 5.7576 3.2600 73.4250 0.0408 -0.0831 1.0100 0.0169 0.7392 1.1322

# Story 2
uniaxialMaterial SAWS 2 21.1164 2.9082 2.9900 50.3094 0.0419 -0.0598 1.0100 0.0160 0.7110 1.1653

#------------------------------------------------------------------------------------

## Define Model

# Shear wall zero length elements

set TrussMatID 600; # define a material ID
set Arigid 1000.0; # define area of truss section (make much larger than A of frame elements)
set Irigid 10000.0; # moment of inertia for p-delta columns (make much larger than I of frame elements)
set Es 29000.0; # steel Young's modulus
#uniaxialMaterial Elastic $TrussMatID $Es; # define truss material

set PDeltaTransf 1;
geomTransf PDelta $PDeltaTransf; # PDelta transformation


uniaxialMaterial Elastic $TrussMatID $Es; # define truss material

## Define Model

# Shear wall zero length elements

element zeroLength 112 120 121 -mat 1 $TrussMatID $TrussMatID -dir 1 2 6 -doRayleigh 1 # Wall 1
element zeroLength 123 130 131 -mat 2 $TrussMatID $TrussMatID -dir 1 2 6 -doRayleigh 1 # Wall 2

element truss 12 111 120 $Arigid $TrussMatID; # Floor 2
element truss 13 121 130 $Arigid $TrussMatID; # Floor 3


# rigid links
# command: element truss $eleID $iNode $jNode $A $materialID
# eleID convention: 6xy, 6 = truss link, x = Bay #, y = Floor #
element truss 2 121 221 $Arigid $TrussMatID; # Floor 2
element truss 3 131 231 $Arigid $TrussMatID; # Floor 3


# p-delta columns
# eleID convention: 7xy, 7 = p-delta columns, x = Pier #, y = Story #
element elasticBeamColumn 212 211 2211 $Arigid $Es $Irigid $PDeltaTransf; # Story 1
element elasticBeamColumn 213 22111 2311 $Arigid $Es $Irigid $PDeltaTransf; # Story 2


rotLeaningCol 5312 221 2211; # top of Story 1 leaning column
rotLeaningCol 5313 221 22111; # bottom of Story 1 leaning column
rotLeaningCol 5314 231 2311; # top of Story 2 leaning column

Thanks,
Jeena